In my example below, I break a string on a word boundary, outputting to an XML element called "NoteMessage" from the PESC standard.  This is dependant on Java, but you could use any language that has a useful lastIndexOf function.  In the case of Java, with zero based string index, we need to compensate for the one based string index that XSL has.  So, we add one to the result of the lastIndexOf() call.

<!--
Example...
java -cp target/dependency/xml-util-0.1.3-SNAPSHOT.jar:/usr/share/xalan/lib/xalan.jar \
org.apache.xalan.xslt.Process -XSL target/classes/xsl/notemessage.xsl \
 -PARAM testString "This is a test to break a string into multiple note messages, \
automatically, without programming."
-->
<xsl:stylesheet version="1.0"
                xmlns:String="http://xml.apache.org/xalan/java/java.lang.String"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="${xml.indent}" method="xml" omit-xml-declaration="yes"/>
  <xsl:param name="testString"/>
  <xsl:variable name="break-at" select="'76'"/>
 
  <xsl:template match="/">
    <xsl:call-template name="note-message">
      <xsl:with-param name="string" select="$testString"/>
    </xsl:call-template>
  </xsl:template>
 
  <xsl:template name="note-message">
    <xsl:param name="string"/>
    <xsl:choose>
      <xsl:when test="string-length($string) <= $break-at">
        <xsl:element name="NoteMessage">
        <xsl:value-of select="$string"/>
        </xsl:element>
      </xsl:when>
      <xsl:otherwise>
        <!-- call method to find word boundary index -->
        <xsl:variable name="truncString"
                      select="String:new(substring($string, 1, $break-at))"/>
        <xsl:variable name="lastSpaceIndex"
                      select="String:lastIndexOf($truncString, ' ') + 1"/>
        <xsl:element name="NoteMessage" namespace="">
          <xsl:value-of select="substring(string($truncString), 1, $lastSpaceIndex)"/>
        </xsl:element>
        <xsl:call-template name="note-message">
          <xsl:with-param name="string"
                          select="substring($string, $lastSpaceIndex + 1)"/>
        </xsl:call-template>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>